alguma macro de pescar na warp vip ?

Também queria o @lomexicano disse que ia fazer um pá noix ;-;

 

E

Eu fiz uma, quando eu chegar em casa eu mando aqui. Ela pesca, repara com /reparar, vai pra uma home jogar o lixo fora e só fica com p4/p3/eff5/eff4/s5/S4 (eu acho, faz dias que não uso kkkkk).
Mas assim, não compensa de verdade pra quem tem alto level de pesca, não vem tanto diamante nem maçã ;-;

 

Pensando por esse lado é verdade :c

 

Vindo dima tá bom

 

Para usar esta macro, deixe seu minecraft em inglês!

Sethomes:
- /home pesqueirovip - dentro do pesqueiro da /warp vip, embaixo da água, olhando para frente (você não morre afogado na warp vip).
- /home lixeira - uma home no mundo 1, para você dropar os lixos fora.

INICIE A MACRO EXATAMENTE NA POSIÇÃO DO /home pesqueirovip
INICIE A MACRO COM A VARA NO SLOT 9, e com todas as linhas que vocês achem que vai gastar (se acabar, a macro só vai parar mesmo, como eu disse antes, é uma macro que eu fiz só pra ver se rendia pescar ali)

Esta macro não dropa fora: p3, p4, eff4, eff5, s4 e s5. Tudo editável no começo do código, se vocês quiserem mudar algo (tirar algum encantamento, por exemplo), é só apagar, dentro da variável lá, isto: |^encantamento_que_voce_nao_quer$

Código:

$${
&home_no_pesqueiro_vip = "/home pesqueirovip"; //// INICIE A MACRO NESSA SETHOME!!!!
&home_na_lixeira = "/home lixeira"
&delay_da_pesca = "300ms";
log("&e&l[MACRO] &0por &8lo&2mex&fic&4ano");
&id_armaduras = "^310$|^311$|^312$|^313$";
&id_ferramentas = "^276$|^277$|^278$|^279$";
&encant_armaduras = "^Protection IV$|^Protection III$";
&encant_ferramentas = "^Sharpness IV$|^Sharpness V$|^Efficiency IV$|^Efficiency V$";
&itens_pra_nao_jogar_fora = "^346$|^287$|^349$|^264$|^265$|^266$|^322$|^369$|^370$|%&id_armaduras%|%&id_ferramentas%";



if(a);unset(a);log("&e&l[MACRO] &6pesca &fna &ewarp vip&f: &4OFF!");stop;else;log("&e&l[MACRO] &6pesca &fna &ewarp vip&f: &2ON!");set(a);endif
///////// INICIE O MACRO NO PESQUEIRO VIP, NA SETHOME INDICADA
echo("%&home_no_pesqueiro_vip%"); wait(1500ms);
#xtrap = %XPOS%; #ytrap = %YPOS%; #ztrap = %ZPOS%;
do();
    do();gui(inventory);until(%GUI% == "GUIINVENTORY");
    do();
        if(%GUI% == "GUICHAT");
            log(" ");
            log("&e&l[MACRO] &6Chat aberto! &fAguardando...");
            do(100);
                wait(300ms);
                if(%GUI% != "GUICHAT");
                    log("&e&l[MACRO] &6Chat fechado! &aRetomando&f...");
                    break;
                endif;
            loop;
            if(%GUI% == "GUICHAT");
                log("&e&l[MACRO] &6Chat ficou aberto tempo demais! &aRetomando&f...");
                wait(3000ms);
                gui(); wait(200ms); do();gui(inventory);until(%GUI% == "GUIINVENTORY");
            endif;
        elseif(%GUI% == "NONE");
            wait(1000ms);
            if(%GUI% == "NONE");
                do();gui(inventory);until(%GUI% == "GUIINVENTORY");
            endif;
        endif;
        pick(346);
        if((%DURABILITY% >= 15)&&(%ITEM% == 346));
            key(use);
            wait(%&delay_da_pesca%);
        elseif((%ITEM% == 346)&&(%DURABILITY% < 15));
            getslot(287,#slot_linha);
            if(#slot_linha >= 0);
                echo("/reparar");
                wait(2000ms);
            else;
                log("&e&l[MACRO] &facabou a linha?");
                log("&e&l[MACRO] &c&lMACRO DESATIVADO!");
                unset(a);
                stop;
            endif;
        elseif(%ITEM% != 346);
            getslot(346,#slot_vara);
            wait(500ms);
            if(#slot_vara < 0);
                log("&e&l[MACRO] &fa vara quebrou?");
                log("&e&l[MACRO] &c&lMACRO DESATIVADO!");
                unset(a);
                stop;
            else;
                slotclick(%#slot_vara%,l,false);
                wait(100ms);
                slotclick(44,l,false);
                wait(100ms);
                slotclick(%#slot_vara%,l,false);
                wait(100ms);
                pick(346);
                wait(500ms);
            endif;
        endif;
        getslotitem(35,#slot35);
        if(#slot35 != 0);
            set(esvaziar);
            break;
        endif;
    loop;
    if(esvaziar); unset(esvaziar);
        #x = %XPOS%; #z = %ZPOS%;
        do();
            echo("%&home_na_lixeira%");
            do(100);
                wait(100ms);
                if((%XPOS% != %#x%)||(%ZPOS% != %#z%));
                    break;
                endif;
            loop;
            if((%XPOS% != %#x%)||(%ZPOS% != %#z%));
                break;
            endif;
        loop;
        wait(500ms);
        do();gui(inventory);until(%GUI% == "GUIINVENTORY");
        unsafe;
            do();gui(inventory);until(%GUI% == "GUIINVENTORY");
            for(#slot,9,44);
                getslotitem(%#slot%,#oq);
                ifmatches(%#oq%,%&itens_pra_nao_jogar_fora%);
                else;
                    ///log(fora);
                    slotclick(%#slot%,l,false);
                    slotclick(-999);
                endif;
            next;
            slotclick(36,l,true);
            SLOT(1);
            wait(100ms);
            for(#slot,9,44);
                getslotitem(%#slot%,#oq);
                ifmatches(%#oq%,%&id_armaduras%);
                    slotclick(%#slot%,l,false);
                    slotclick(36,l,false);
                    slotclick(%#slot%,l,false);
                    foreach(enchantments);
                        ifmatches(%ENCHANTMENT%,%&encant_armaduras%);
                            &encantamento_encontrado = "%ENCHANTMENT%";
                            set(guardar_isso);
                            break;
                        endif;
                    next;
                endif;
                ifmatches(%#oq%,%&id_ferramentas%);
                    slotclick(%#slot%,l,false);
                    slotclick(36,l,false);
                    slotclick(%#slot%,l,false); 
                    foreach(enchantments);
                        ifmatches(%ENCHANTMENT%,%&encant_ferramentas%);
                            &encantamento_encontrado = "%ENCHANTMENT%";
                            set(guardar_isso);
                            break;
                        endif;
                    next;
                endif;
                if(guardar_isso);
                    log("&e&l[MACRO] &fGuardar este &6%&encantamento_encontrado%&f!");
                    slotclick(36,l,true);
                else;
                    slotclick(36,l,false);
                    slotclick(-999);
                endif;
                unset(guardar_isso);
            next;
            #slotvazio = 0;
            for(#slot,9,44);
                getslotitem(%#slot%,#oq);
                if(#oq == 0); #slotvazio = #slot; endif;
                if(#slotvazio >= 9);
                    slotclick(35,l,false);
                    slotclick(%#slotvazio%,l,false);
                    break;
                endif;
            next;
            if(#slotvazio < 9);
                log("&e&l[MACRO] &fNao tem slot vazio no inventario?");
                log("&e&l[MACRO] &c&lMACRO DESATIVADO!");
                unset(a);
                stop;
            endif;
            gui();
        endunsafe;
      
        do();
            echo("%&home_no_pesqueiro_vip%");
            do(100);
                wait(100ms);
                if((%XPOS% == %#xtrap%)&&(%YPOS% == %#ytrap%)&&(%ZPOS% == %#ztrap%));
                    break;
                endif;
            loop;
            if((%XPOS% == %#xtrap%)&&(%YPOS% == %#ytrap%)&&(%ZPOS% == %#ztrap%));
                break;
            endif;
        loop;
    endif;
loop;
}$$

 

O Meu Abre o Inventário e Fica Parado sem fazer mais nada e-e
fiz algo errado? lol
*resolvi *

 

eoq? kkkkkkkkk q q tinha dado?

 

Cara, pra falar a verdade, pesca ta rendendo a mesma coisa em qualquer lugar do servidor que você for.

Sim, eles nerfaram até isso.

Então acho que mais compensa você pegar o macro do sleep e fazer o seu próprio pesqueiro, uma vez que vai render a mesma coisa em qualquer lugar.

 

sim, vale mais a pena deixar em mundo region, pq o tempo todo alguém ativa xp vip, ou em mundo 1, para não bugar os itens (e dizem que dá mais drop) ..
isso aqui era só pra testar os diamantes do pesqueiro vip mesmo

valeu man

 

opa estamos a espera d0 macrooooooo

 

Mas é aquela coisinha simples alí mesmo ☝️ kkkkkk falei que era simplão

 

Acho que não existe migo

 

Acho que já existe migo