ENTREGUE [MACRO] - Melhor macro de mensagens automáticas.

Olá galera, beleza? Olha eu aqui de novo, o Gre, pra postagem de uma macro foda!

O que esse macro faz?

• 
  
  
  • Um macro completo de mensagens pela interface básica do mine.
  • Pode iniciar e começar o macro do zero.
  • Pode adicionar, editar ou excluir mensagens.
  • Escolha o delay entre mensagens.
  • Faça navegação pelo menu.
  • Reciclar mensagens.
  • Fácil navegação.
  • Veja a lista de mensagem.
  • Totalmente aleatório.
  • Sem limites de mensagem.
  • Você pode adicionar comandos como /anuncio, /g ou /megafone +msgm.

"A _Gre, mas fazer um macro de mensagem é fácil." - Eu sei gente, por isso eu fiz esse, pra mostrar a capacidade do macro. E também pra simplificar a vida de quem não quer ficar abrindo os menus toda hora pra fazer edição. Ele é bem fácil de usar, basicamente segue os prints, e é isso .

O delay máximo é de um digito de até 4 números (Até 9999);
Na caixa prompt só será enviada ao chat a capacidade máxima de fala no server;
As mensagens ficam salvas em variáveis listadas, ou tais arrays, então não mecha no código para edição de mensagem que não adianta, bjs <3

Prints:


Código - Só precisa colocar na tecla e ser feliz e se gostou, deixe seu like <3

Spoiler: Código

Código:

$${
    IF(gre_messeg);
        SET(#delay,%#delay%);
        SET(&msg,%&msg%);
        UNSET(gre_messeg);
        LOG(&a[&f&l!&a] &cMacro encerrado!);
        STOP(msg);
        STOP;
    ELSE;
        WAIT(2);
        SET(gre_messeg);
        SET(&msgdel,"§c§mMensagem Deletada!");
        #tempo=1;
        #restante=30;
        #tempod=11;
        #ldel=%#nr%*2;
        DO;
        SET(#resposta,0);
            DO;
                DO;
                    CLEARCHAT();
                    LOG("");
                    LOG("§a[§f§l!§a] §aPressione §f§lESPAÇO §apara §aresetar §aas §amensagens!");
                    LOG("§a[§f§l!§a] §aPressione §f§lENTER §apara §ainiciar §acom §aas §amensagens §asalvas!");
                    LOG("§a[§f§l!§a] §aPressione §f§lCTRL §apara §aadicionar §anovas §amensagens!");
                    LOG("§a[§f§l!§a] §aPressione §f§lSHIFT §apara §aeditar §aalguma §amensagem!");
                    LOG("§a[§f§l!§a] §aPressione §f§lTAB §apara §aver §aas §amensagem!");
                    LOG("§a[§c§l!§a] §8§lVocê tem §c%#restante% segundos");
                    IF((KEY_RETURN)||(KEY_NUMPADENTER));
                        SET(#resposta,1);
                        LOG("&a[&f&l!&a] &aReciclando anuncios!");
                        BREAK;
                    ENDIF;
                    IF(KEY_SPACE);
                        SET(#resposta,2);
                        LOG("&a[&f&l!&a] &aNovos anuncios!");
                        BREAK;
                    ENDIF;
                    IF((KEY_LSHIFT)||(KEY_RSHIFT));
                        SET(#resposta,3);
                        LOG("&a[&f&l!&a] &aEditando anuncios!");
                        BREAK;
                    ENDIF;
                    IF((KEY_LCONTROL)||(KEY_RCONTROL));
                        SET(#resposta,4);
                        LOG("&a[&f&l!&a] &aAdicionar novas mensagens!");
                        BREAK;
                    ENDIF;
                    IF((KEY_TAB));
                        #i=1;
                        LOG("§8[§clista§8] §f- Lista das mensagens.");
                        DO(%#nr%);
                            LOG("§8[§7ID] §c%#i%");
                            LOG("§8[§7Delay§8] §e%#delay[%#i%]%");
                            LOG("§f- %&msg[%#i%]%");
                            LOG("");
                            INC(#i);
                            WAIT(3T);
                        LOOP;
                        WAIT(%#ldel%);
                    ENDIF;
                    WAIT(10ms);
                    #tempo=%#tempo%+1;
                UNTIL(%#tempo%=%#tempod%);
                #tempod=%#tempod%+10;
                #restante=%#restante%-1;
                IF(%#restante%<=0);
                    SET(#delay,%#delay%);
                    SET(&msg,%&msg%);
                    UNSET(gre_messeg);
                    LOG(&a[&f&l!&a] &cMacro encerrado por falta de resposta!);
                    STOP(msg);
                    STOP;
                ENDIF;
            UNTIL((%#restante%<=0)||(%#resposta%>0));
            LOG("§a[GMacro] §7Obrigado por utilizar essa macro, Bjs _Gre :p");
            LOG("");
            WAIT(5T);
            //
            // Reciclagem -
            //
            IFMATCHES(%#resposta%,1);
                IFMATCHES(%#nr%,0);
                    SET(#delay,%#delay%);
                    SET(&msg,%&msg%);
                    UNSET(gre_messeg);
                    LOG(&a[&f&l!&a] &cMacro encerrado por falta de mensagens!);
                    STOP(msg);
                    STOP;
                ENDIF;
                LOG("&a[&f&l!&a] &aIniciando mensagens!");
                RANDOM(#i,1,%#nr%);
                DO;
                    IFMATCHES(%&msgdel%,%&msg[%#i%]%);
                    ELSE;
                        IF(%#nr%=1);
                            SET(#i,0);
                        ENDIF;
                        IF(%#nr%=%#i%);
                            SET(#i,1);
                        ELSE;
                            INC(#i);
                        ENDIF;
                            LOG("");
                            LOG("§8[§7ID] §c%#i%");
                            LOG("§8[§7Delay§8] §e%#delay[%#i%]%");
                            LOG("§f- %&msg[%#i%]%");
                            LOG("");
                        WAIT(1T);
                        ECHO(%&msg[%#i%]%);
                        RANDOM(#i,1,%#nr%);
                        WAIT(%#delay[%#i%]%);
                    ENDIF;
                LOOP;
            ENDIF;
            //
            // Reset de mensagens -
            //
            IFMATCHES(%#resposta%,2);
                PROMPT(#nr,$$?,"§aQuantas mensagens deseja adicionar?",,0);
                #i=1;
                IFMATCHES(%#nr%,0);
                    SET(#delay,%#delay%);
                    SET(&msg,%&msg%);
                    UNSET(gre_messeg);
                    LOG(&a[&f&l!&a] &cMacro encerrado por falta de mensagens!);
                    STOP(msg);
                    STOP;
                ENDIF;
                DO(%#nr%);
                    PROMPT(&msg[%#i%],$$?,"§a%#i%ª Mensagem -",,NONE);
                    IFMATCHES(NONE,%&msg[%#i%]%);
                    ELSE;
                        IFMATCHES(%#i%,%#nr%);
                            PROMPT(#delay[%#i%],$$?,"§aDelay para a§a primeira mensagem -",,0000);
                        ELSE;
                            PROMPT(#delay[%#i%],$$?,"§aDelay para a§a próxima mensagem -",,0000);
                        ENDIF;
                        INC(#i);
                    ENDIF;
                    WAIT(1);
                LOOP;
            ENDIF;
            //
            // Edição de mensagens -
            //
            IFMATCHES(%#resposta%,3);
                #i=1;
                LOG("§8[§clist§8] §f- Lista das mensagens.");
                DO(%#nr%);
                        LOG("§8[§7ID] §c%#i%");
                        LOG("§8[§7Delay§8] §e%#delay[%#i%]%");
                        LOG("§f- %&msg[%#i%]%");
                        LOG("");
                    INC(#i);
                LOOP;
                WAIT(%#ldel%);
                PROMPT(#i,$$?,"§aQual mensagem deseja editar? - Coloque o ID.");
                WAIT(500ms);
                IFMATCHES(%#i%,0);
                ELSE;
                    LOG("&c[&f&l!&c] &cPara manter a mensagem deixe em branco!");
                    WAIT(1);
                    PROMPT(&msg[%#i%],$$?,"§a%#i%ª Mensagem -",,%&msg[%#i%]%);
                    PROMPT(#delay[%#i%],$$?,"§aDelay para a próxima mensagem ou deixe em branco para deletar.",,0000);
                    IFMATCHES(%#delay[%#i%]%,0000);
                        UNSET(&msg[%#i%]);
                        UNSET(#delay[%#i%]);
                        log('-');
                    ENDIF;
                ENDIF;
                #i=1;
                LOG("§8[§clist§8] §f- Lista das mensagens.");
                DO(%#nr%);
                        LOG("§8[§7ID] §c%#i%");
                        LOG("§8[§7Delay§8] §e%#delay[%#i%]%");
                        LOG("§f- %&msg[%#i%]%");
                        LOG("");
                    INC(#i);
                LOOP;
                WAIT(%#ldel%);
            ENDIF;
            //
            // Adicionar mensagens -
            //
            IFMATCHES(%#resposta%,4);
                #i=1;
                LOG("§8[§clist§8] §f- Lista das mensagens.");
                DO(%#nr%);
                        LOG("§8[§7ID] §c%#i%");
                        LOG("§8[§7Delay§8] §e%#delay[%#i%]%");
                        LOG("§f- %&msg[%#i%]%");
                        LOG("");
                    INC(#i);
                LOOP;
                WAIT(%#ldel%);
                PROMPT(#mnr,$$?,"§aQuantas mensagens deseja adicionar? - ");
                INC(#nr,%#mnr%);
                DO(%#mnr%);
                    PROMPT(&msg[%#i%],$$?,"§a%#i%ª Mensagem -",,NONE);
                    IFMATCHES(NONE,%&msg[%#i%]%);
                    ELSE;
                        IFMATCHES(%#i%,%#nr%);
                            PROMPT(#delay[%#i%],$$?,"§aDelay para a§a primeira mensagem -",,0000);
                        ELSE;
                            PROMPT(#delay[%#i%],$$?,"§aDelay para a§a próxima mensagem -",,0000);
                        ENDIF;
                        INC(#i);
                    ENDIF;
                LOOP;
                #i=1;
                LOG("§8[§clist§8] §f- Lista das mensagens.");
                DO(%#nr%);
                        LOG("§8[§7ID] §c%#i%");
                        LOG("§8[§7Delay§8] §e%#delay[%#i%]%");
                        LOG("§f- %&msg[%#i%]%");
                        LOG("");
                    INC(#i);
                LOOP;
                WAIT(%#ldel%);
            ENDIF;
        LOOP;
    ENDIF;
}$$

Como colocar o macro nesse post - Clique Aqui

#Edits / Changelog -

Spoiler

Edit 1 - Esqueci de adicionar a quantidade máxima de dezenas e o cancelamento ao atingir o tempo máximo.

 

A partir do momento que você liga ela e escolhe uma das opções você consegue escrever em um prompt (caixa de texto), o que enviar no chat, pode ser tanto comando quanto texto normal. usando o comando "echo" que replica a variável ou mensagem no seu chat.

 

É um modpack próprio, mexo com isso a pouco tempo, só 4/5 anos :v já tenho portfólio. Tenho muito macro, vou começar a postar gratuito alguns, outros são outra história.

Ainda não, mas vou adicionar, provavelmente amanhã ou quinta no máximo. acho q só tem que editar 2 coisas, mas tenho que reibaixar liteloader pra 152

 

asghhdasd, uma por vez, ora. Ele manda em ordem aleatória ainda :3

 

@Up

 

tanto 1.7 quanto 1.8 ou superior.